********Übung 5**********



**Aufgabe 1**

*Da die Variable "Geschlecht" binärer Natur ist, rechnen wir T-Tests für unabhängige Stichproben.

*Hierfür sollten wir die Textvariable "Geschlecht" in eine numerische Variable umkodieren und mit passenden Wertelabels versehen.*

RECODE Geschlecht ('m'=0) ('w'=1) INTO Geschlecht_num.
EXECUTE.

VALUE LABELS Geschlecht_num 0 "männlich" 1 "weiblich".

NPAR TESTS
  /M-W= neurspeed Testosteron Testleistung BY Geschlecht_num(0 1)
  /MISSING ANALYSIS.


T-TEST GROUPS=Geschlecht_num(0 1)
  /MISSING=ANALYSIS
  /VARIABLES=neurspeed IQ_IST IQ_HAWIE Testosteron @EQ Testleistung
  /CRITERIA=CI(.95).


*Für den Fall, dass unsere Annahme der Normalverteilung für die 6 Variablen nicht korrekt war, rechnen wir U-Tests.*


NPAR TESTS
  /M-W=neurspeed IQ_IST IQ_HAWIE Testosteron @EQ Testleistung BY Geschlecht_num(0 1)
  /MISSING ANALYSIS.


*Wir sehen, dass es nur beim Testosterongehalt einen signifikanten Geschlechtsunterschied gibt (Männer haben höhere Werte).*

*Weiterhin erkennen wir, dass dass die Ergebnisse der U-Tests inhaltlich identisch mit den Ergebnissen der t-Tests sind. Der t-Test ist relativ robust gegenüber Verletzungen der Normalverteilung.*
*Daher sind leichte Verletzungen der Normalverteilung bei ausreichender Stichprobengröße (n pro untersuchter Gruppe min. 25) kein Problem in Bezug auf den T-Test.




**Aufgabe 2**

GRAPH
  /BAR(SIMPLE)=MEAN(neurspeed) BY Geschlecht.

GRAPH
  /BAR(SIMPLE)=MEAN(IQ_IST) BY Geschlecht.

GRAPH
  /BAR(SIMPLE)=MEAN(IQ_HAWIE) BY Geschlecht.

GRAPH
  /BAR(SIMPLE)=MEAN(Testosteron) BY Geschlecht.

GRAPH
  /BAR(SIMPLE)=MEAN(@EQ) BY Geschlecht.

GRAPH
  /BAR(SIMPLE)=MEAN(Testleistung) BY Geschlecht.

*Die Balkendiagramme zeigen wie die Signifikanztests deutlich, dass nur bei der Variable Testosteron Geschlechtsunterschiede bestehen.*


**Aufgabe 3a - geschlechtsneutrale Sicht**


*Da die beiden IQ-Tests identisch skaliert sind, rechnen wir T-Tests für abhängige Stichproben.*

T-TEST PAIRS=IQ_IST WITH IQ_HAWIE (PAIRED)
  /CRITERIA=CI(.9500)
  /MISSING=ANALYSIS.


*Für den Fall, dass unsere Annahme der Normalverteilung für die beiden Variablen nicht korrekt war, rechnen wir noch einen Wilcoxon-Test.*

NPAR TESTS
  /WILCOXON=IQ_IST WITH IQ_HAWIE (PAIRED)
  /STATISTICS DESCRIPTIVES 
  /MISSING ANALYSIS.


*Wir sehen bei beiden Tests, dass der HAWIE einen signifkant besseren IQ liefert als der IST.*


**Aufgabe 3b - in Abhängigkeit vom Geschlecht**


*Zuerst teilen wir den Datensatz nach der Variable "Geschlecht" auf.*
 
SORT CASES  BY Geschlecht.
SPLIT FILE LAYERED BY Geschlecht.

*Danach rechnen wir den T-Test und den WIlcoxon-Test noch einmal.*

T-TEST PAIRS=IQ_IST WITH IQ_HAWIE (PAIRED)
  /CRITERIA=CI(.9500)
  /MISSING=ANALYSIS.


NPAR TESTS
  /WILCOXON=IQ_IST WITH IQ_HAWIE (PAIRED)
  /STATISTICS DESCRIPTIVES 
  /MISSING ANALYSIS.


*Aus den Ergebnissen ist ersichtlich, dass es sich um einen vom Geschlecht unabhängigen Effekt handelt, da der HAWIE im Vergleich zum IST sowohl bei den Frauen aus auch bei den Männern den signifikant besseren IQ liefert.*



**Aufgabe 4**

*Zuerst heben wir die Teilung unseres Datensatzes wieder auf:*

SPLIT FILE OFF.

FREQUENCIES VARIABLES=neurspeed
  /FORMAT=NOTABLE
  /NTILES=4
  /STATISTICS=MINIMUM MAXIMUM
  /ORDER=ANALYSIS.


*Die Häufigkeitsanalyse mit Ausgabe der Quartile zeigt uns, dass bei 4 Klassen die Klassenbreite relativ gering ist.*
*Wir entscheiden uns daher für drei Klassen.*


FREQUENCIES VARIABLES=neurspeed
  /NTILES=3
  /STATISTICS=RANGE MINIMUM MAXIMUM
  /ORDER=ANALYSIS.

RECODE neurspeed (Lowest thru 18.5=1) (18.5001 thru 22.6=2) (22.6001 thru Highest=3) INTO 
    neurspeed_klass.
EXECUTE.

VALUE LABELS neurspeed_klass 1 "bis 18,5" 2 ">18,5 bis 22,6" 3 ">22,6".


GRAPH
  /BAR(SIMPLE)=COUNT BY neurspeed_klass.

*Das Balkendiagramm zeigt, dass wir drei in etwa gleich große Gruppen gebildet haben.*




**Aufgabe 5**

*Zuerst teilen wir den Datensatz nach der Variable "Geschlecht" auf.*
 
SORT CASES  BY Geschlecht.
SPLIT FILE LAYERED BY Geschlecht.

*Danach erstellen wir die Fehlerbalkendiagramme in zusätzlicher Abhängigkeit der kategorisierten Variable "neurspeed".*

GRAPH
  /ERRORBAR(CI 95)=Testleistung BY neurspeed_klass.

*Hierbei erkennen wir einen Haupteffekt der Variable neurspeed. Da sowohl bei den weiblichen als auch bei den männlichen Versuchspersonen*
*die Testleistung bei Zunahme der Nervenleitgeschwindigkeit steigt, gehen wir davon aus, dass es bei diesem Sachverhalt keine Interaktion "Geschlecht x neurspeed" gibt.*


**Aufgabe 6**

*Zuerst heben wir die Teilung unseres Datensatzes wieder auf:*

SPLIT FILE OFF.

*Danach erstellen wir eine Kreuztabelle und aktivieren hierbei "Chi-Quadrat" und die "Erwarteten Häufigkeiten".*

CROSSTABS
  /TABLES=Geschlecht BY neurspeed_klass
  /FORMAT=AVALUE TABLES
  /STATISTICS=CHISQ 
  /CELLS=COUNT EXPECTED 
  /COUNT ROUND CELL.

*Wir erkennen anhand des insignifikanten Chi-Quadrat-Tests und der Kreuztabelle, dass die beiden Variablen stochastisch unabhängig voneinander sind.*


**Aufgabe 7**

*Wir berechnen eine zweifaktorielle ANOVA mit Geschlecht als festem und neurspeed_klass als Zufallsfaktor.*

UNIANOVA Testleistung BY Geschlecht neurspeed_klass
  /RANDOM=neurspeed_klass
  /METHOD=SSTYPE(3)
  /INTERCEPT=INCLUDE
  /PLOT=PROFILE(Geschlecht*neurspeed_klass)
  /PRINT=DESCRIPTIVE
  /CRITERIA=ALPHA(.05)
  /DESIGN=Geschlecht neurspeed_klass Geschlecht*neurspeed_klass.

*Wir finden den aufgrund der Fehlerbalkendiagramme vermuteten Haupteffekt der Nervenleitgeschwindigkeit. Je höher die Nervenleitgeschwindigkeit, desto höher ist die Testleistung.*
*Es existiert kein Geschlechtshaupteffekt und auch wie vermutet keine Interaktion. Das Profildiagramm bestätigt dies.*